| 

.NET C# Java Javascript Exception

3
Wie kann ich nicht nur allgemeine Festplattendaten mitsamt der Anzahl der Partitionen per WMI, sondern auch detaillierte Informationen zu den einzelnen Partitionen selbst (interner Name, ggfs. zugeordneter Laufwerksbuchstabe, ggfs. Verknüpfung an andere Partition, physikalische Speicherinformationen, Start- und Endblock) abfragen? Über WMI habe ich nichst entsprechendes gefunden.
News:
17.10.2013
Peter Pan 313 1 7
1 Antwort
1
Also Laufwerksbuchstaben usw. geht. Hier ein Ausschnitt aus der MSDN:

ComputerName = "."
Set wmiServices = GetObject ( _
"winmgmts:{impersonationLevel=Impersonate}!//" _
& ComputerName)
' Get physical disk drive
Set wmiDiskDrives = wmiServices.ExecQuery ( _
"SELECT Caption, DeviceID FROM Win32_DiskDrive")

For Each wmiDiskDrive In wmiDiskDrives
WScript.Echo "Disk drive Caption: " _
& wmiDiskDrive.Caption _
& VbNewLine & "DeviceID: " _
& " (" & wmiDiskDrive.DeviceID & ")"

'Use the disk drive device id to
' find associated partition
query = "ASSOCIATORS OF {Win32_DiskDrive.DeviceID='" _
& wmiDiskDrive.DeviceID & "'} WHERE AssocClass = Win32_DiskDriveToDiskPartition"
Set wmiDiskPartitions = wmiServices.ExecQuery(query)

For Each wmiDiskPartition In wmiDiskPartitions
'Use partition device id to find logical disk
Set wmiLogicalDisks = wmiServices.ExecQuery _
("ASSOCIATORS OF {Win32_DiskPartition.DeviceID='" _
& wmiDiskPartition.DeviceID & "'} WHERE AssocClass = Win32_LogicalDiskToPartition")

For Each wmiLogicalDisk In wmiLogicalDisks
WScript.Echo "Drive letter associated" _
& " with disk drive = " _
& wmiDiskDrive.Caption _
& wmiDiskDrive.DeviceID _
& VbNewLine & " Partition = " _
& wmiDiskPartition.DeviceID _
& VbNewLine & " is " _
& wmiLogicalDisk.DeviceID
Next
Next
Next


Zusätzlich dazu gibt es hier noch einen Link zur MSDN:
MSDN WMI Hard Disk Information

Und hier noch ein echt praktisches Tool von Microsoft: WMI Object Browser

WMI Object Browser / WMI Tools

Gruß
17.10.2013
Gott 176 1
Vielen Dank, nun komme ich zumindest an die einzelnen Partitionen. Fehlen nur noch die physikalischen Speiucherinfos und Start- und Endblockangaben.
Peter Pan 18.10.2013
Kein Problem, vielleicht hilft dir die Klasse: Win32_DiskPartition aus der WMI weiter. Dort gibt es die Eigenschaften: NumberOfBlocks, BlockSize und StartOffset. Damit solltest du eigentlich alles Berechnen können.

Hier die Referenz
http://msdn.microsoft.com/en-us/library/aa394135(v=vs.85).aspx
Gott 18.10.2013
Genial... genau das habe ich gesucht. Danke für die tollen Hinweise!
Peter Pan 21.10.2013

Stelle deine .net-Frage jetzt!
TOP TECHNOLOGIES CONSULTING GmbH